IF(logical_test,value_if_true,value_if_false)
Logical_test 是用來計算 TRUE 或 FALSE 的任何值或運算式。
Value_if_true 係指 logical_test 為 TRUE 時所傳回的值。
Value_if_false 如果 logical_test 為 FALSE，則會傳回該值。
範例1
計算資遣費之預告工資
平均工資 A1
工作年資 A2
預告工資 A3
預告工資條件：
１．年資滿3個月、未滿1年，發給10日預告工資
２．年資滿1年、未滿3年，發給20日預告工資
３．年資滿3年以上，發給30日預告工資
預告工資 A3 = IF(A2>3,A1, IF(A2>1,A1*2/3,IF(A2>0.25,A1/3,0)))
第一層公式
Logical_test ：A2>3 (年資滿3年以上)
Value_if_true ：A1 (上述條件為true，發給30日預告工資)
Value_if_false ： IF(A2>1,A1*2/3,IF(A2>0.25,A1/3,0)) (上述條件為false)
第二層公式
Logical_test ：A2>1 (年資滿1年、未滿3年)
Value_if_true ：A1*2/3 (上述條件為true，發給20日預告工資)
Value_if_false ：IF(A2>0.25,A1/3,0) (上述條件為false)
第三層公式
Logical_test ：A2>0.25 (年資滿3個月、未滿1年)
Value_if_true ：A1/3 (上述條件為true，發給10日預告工資)
Value_if_false ：0 (上述條件為false)
範例2
有價證券上櫃費之計算
| A | B | C | ||
| 1 | 民國XX年度 | |||
| 2 | 掛牌金額 (元) | 掛牌月份 | ||
| 3 | ||||
| 4 | 上櫃有價證券總面值 | 上櫃費費率 | ||
| 5 | 三億元以下 | 300,000,000 | 0.0400% | |
| 6 | 超過三億元至五億元部分 | 500,000,000 | 0.0300% | |
| 7 | 超過五億元至十億元部分 | 1,000,000,000 | 0.0200% | |
| 8 | 超過十億元至二十億元部分 | 2,000,000,000 | 0.0100% | |
| 9 | 超過二十億元至三十億元部分 | 3,000,000,000 | 0.0050% | |
| 10 | 超過三十億元部分 | 0.0025% | ||
| 11 | 合計金額 (元) (1) | |||
| 12 | 應計算金額 (元) ( 3 ) | 不足十萬以十萬元計 ( 2 ) | 「以( 1 )或( 2 )較高者為主」 | |
| 13 | 應繳金額 ((3)*掛牌月份) | 每年上櫃費最高四十五萬元 | ||
=IF(B5>$B$2,ROUND($B$2*C5,0),ROUND(B5*C5,0))
掛牌金額小於三億元，直接用掛牌金額x上櫃費費率，反之用三億元x上櫃費費率
超過三億元至五億元部分
=IF($B$2>B6,ROUND((B6-B5)*C6,0),IF($B$2-B5>0,ROUND(($B$2-B5)*C6,0),""))
掛牌金額大於五億元，用(五億-三億)x上櫃費費率，反之參考第2層公式
第2層公式IF($B$2-B5>0,ROUND(($B$2-B5)*C6,0),"")
(掛牌金額-三億元)大於0，(掛牌金額-三億)x上櫃費費率，反之不予計算
超過五億元至十億元部分
=IF($B$2>B7,ROUND((B7-B6)*C7,0),IF($B$2-B6>0,ROUND(($B$2-B6)*C7,0),""))
掛牌金額大於十億元，用(十億-五億)x上櫃費費率，反之參考第2層公式
第2層公式IF($B$2-B6>0,ROUND(($B$2-B6)*C7,0),"")
(掛牌金額-五億元)大於0，(掛牌金額-五億)x上櫃費費率，反之不予計算
超過十億元至二十億元部分
=IF($B$2>B8,ROUND((B8-B7)*C8,0),IF($B$2-B7>0,ROUND(($B$2-B7)*C8,0),""))
掛牌金額大於二十億元，用(二十億-十億)x上櫃費費率，反之參考第2層公式
第2層公式IF($B$2-B7>0,ROUND(($B$2-B7)*C8,0),"")
(掛牌金額-十億元)大於0，(掛牌金額-十億)x上櫃費費率，反之不予計算
超過二十億元至三十億元部分
=IF($B$2>B9,ROUND((B9-B8)*C9,0),IF($B$2-B8>0,ROUND(($B$2-B8)*C9,0),""))
掛牌金額大於三十億元，用(三十億-二十億)x上櫃費費率，反之參考第2層公式
第2層公式IF($B$2-B8>0,ROUND(($B$2-B8)*C9,0),"")
(掛牌金額-二十億元)大於0，(掛牌金額-二十億)x上櫃費費率，反之不予計算
超過三十億元部分
=IF($B$2>B9,ROUND(($B$2-B9)*C10,0),"")
掛牌金額大於三十億元，直接用(掛牌金額-三十億)x上櫃費費率，反之不予計算
應計算金額
=IF(D11>100000,D11,100000)
合計金額大於十萬，以合計金額計，反之不足十萬以十萬元計
應繳金額
=IF(ROUND(D12*((12-D2+1)/12),0)<450000,ROUND(D12*((12-D2+1)/12),0),450000)
(應計算金額x掛牌月份)<四十五萬元，以(應計算金額x掛牌月份)計，反之以最高四十五萬元計
----------------------------------------- 同場加映感謝場 ---------------------------------------------------
2-3使用插入函數按鈕
Ｅxcel 提供財務、統計、日期、資料庫、文字串處理等各種類型的函數，運用這些函數來計算求值，可以減輕很多複雜的運算。在儲存格中常用的求值函數如下：
|
名稱 |
儲存格內容（例） |
代表的意義 |
|
加總 |
=SUM(B3:B9,C3,D9) |
加總B3:B9 及儲存格C3、D9 的值 |
|
平均 |
=AVERAGE(A3:A9) |
顯示A3:A9 數值儲存格的平均值 |
|
將數字四捨五入 |
=ROUND(number,num_digits) |
Number 是您想執行四捨五入的數字。Num_digits 是數字執行四捨五入計算時所指定的位數。 |
|
計數 |
=COUNT(A3:A9) |
顯示A3:A9有幾格格位有數字 |
|
最大值 |
=MAX(B3:B9,C3:C9) |
顯示B3:B9 及C3:C9 兩範圍內的最「大」值 |
|
中間數 |
=MEDIAN(B3:B9) |
顯示B3:B9範圍內的「中間數」 |
|
最小值 |
=MIN(B3:B9,C3:C9) |
顯示B3:B9 及C3:C9 兩範圍內的最「小」值 |
|
計算名次 |
=RANK(排序格位，比較範圍，0或1)比較範圍要用”絕對格位” |
依據第一個的數字，在此範圍內比較並排出順序，0表由大到小、1表由小到大 |
|
備註: 2選1 |
=IF(B9>200,"浪費","節儉") （條件，成立時，否則） |
B9 的值如大於200，顯示“浪費”，B9 的值如小於或等於200，顯示“節儉” |
|
3選1 |
=IF(J2>=80,”甲等”,IF(J2>=60, “乙等”,”丙等”） |
三選一 |
※在插入函數方塊中的函數類別將函數依性質予以分類；
函數名稱表示某一個函數類別中使用的函數名稱；
函數類別名稱底下顯示所選定函數的用法；
※Excel格位編號分成：相對格位、絕對格位、混合格位三種方式：
相對格位：複製到其他格位會改變，例如A3:A8、C12、….
絕對格位：在列號及藍號前都加上＄符號（用錢收買）。特性為「將絕對格位複製獲頒移到任何新工作格位時，都會指定原公式的位址」
混合格位：複製時有＄者不改變，沒有＄者會改變
2-4條件運算
有些函數，例如條件函數，通常需要在運算式加入條件運算符號，這些符號包括：＝等於、＜小於、＞大於、＞＝大於或等於、＜＝小於或等於、＜＞不等於
COUNTIF( )函數用法
1. COUNTIF( )用來傳回符合條件非空儲存格的個數，格式為=COUNTIF(範圍, "條件準則的值")。
３設定儲存格格式化條件
實例：設定B5:B8 儲存格低於60 分時顯示紅色，否則為黑色。
1. 選定B5:B8 為作用儲存格；
2. 選格式功能表，選擇設定格式化條件選項；
3. 螢幕顯示設定格式化條件視窗；
4. 將儲存格的值旁的項目設定為小於，旁邊的格內填入60；
5. 選右方的格式，將色彩設定為紅色後，連按兩次確定即可。
※儲存格字型格式：同一格位可以設定不同的字型
方法一、格式工具列設定
方法二、按選【格式（O）】【儲存格（E）】【字型】選擇所需
※分頁預覽：【檢視（V）】【分頁預攬（P）】
預覽分頁是顯示您的工作表列印出來的編輯模式。在預覽分頁中，您可以藉著向左、右、上或下拖曳分頁符號來移動它們。Excel 會自動地縮放工作表以符合此頁的欄和列。
※表格及框線
將外框套用到儲存格上
1. 選取想要加入框線的儲存格；
2. 在[格式] 工具列上按一下[框線]鈕；
3. 若要套用不同的框線樣式，先按一下框線旁邊的箭頭，然後在色板上按一下框線。
其它框線的設定
若要套用其它的框線樣式，請按一下[格式] 功能表上的[儲存格]，然後再按[外框] 索引標籤。按一下您要的線條樣式，然後按需要的按鈕來指定框線位置。
※輸入以0為開頭的資料
解法一：結果是數值（可以計算）-按【格式】【儲存格】【儲存格格式】對話方塊，選【數值】頁，左側【類別】選【自訂】，右側【類型】輸入三個000，最後按【確定】
解法二：結果是文字（無法計算）-先按’符號，再輸入資料，按下〔Enter〕鍵後，雖然0還在，但是它是文字，是無法計算的！
※建立密碼
【檔案】【另存新檔】-鍵入檔名-【工具L】【一般選項G】
輸入：保護密碼及防寫密碼
保護密碼：有密碼才能開啟，
防寫密碼：不知密碼就只能以唯讀開啟，需另存新檔
※凍結窗格
『視窗（W）』『凍結窗格（F）』
留言列表
【1號屋】砍掉重練大作戰 (2)
